home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO001.dsk
/
STARTUP.bas
< prev
Wrap
BASIC Source File
|
2012-02-16
|
2KB
|
57 lines
100 REM STARTUP
110 REM
120 REM DESCRIBE OR INVOKE THE
130 REM PROGRAMS ON THIS DISK.
140 REM SES (COMPUTING) INC.
150 NORMAL : PRINT CHR$(21): TEXT : HOME : VTAB 11
160 D$ = CHR$(4):F$ = "MENU": PRINT D$"PREFIX /IAC.42"
170 PRINT " READING "F$". PLEASE WAIT ..."
180 PRINT D$"OPEN"F$
190 PRINT D$"READ"F$
200 INPUT N$: REM NAME OF DISK
210 INPUT NA: DIM AE$(NA),AC$(NA)
220 FOR I = 1 TO NA: INPUT AE$(I),AC$(I): NEXT
230 IF PEEK(49152) = 160 THEN AB = 1: GOTO 280
240 INPUT NP,ML: DIM NL(NP),PD$(NP,ML)
250 FOR I = 1 TO NP: INPUT PD$(I,0):J = 0
260 INPUT Z$: IF Z$ >" " THEN J = J +1:PD$(I,J) = Z$: GOTO 260
270 NL(I) = J: NEXT
280 PRINT D$"CLOSE"
290 FOR A = 768 TO 787: READ X: POKE A,X: NEXT
300 POKE 48688,0: POKE 48689,3
310 GOSUB 440
320 PRINT : PRINT : PRINT : FOR I = 1 TO NA
330 PRINT " ";: INVERSE : PRINT SPC( I <10)I;: NORMAL : PRINT " "AE$(I): IF NA <8 THEN PRINT
340 NEXT
350 VTAB 22: CALL -958: PRINT " ENTER A NUMBER FROM 1 TO "NA": ";
360 POKE 49168,0: INPUT "";Z$
370 I = VAL(Z$): IF I <1 OR I >NA GOTO 350
380 IF I = (NA) THEN HOME : END
390 IF I = NA -1 GOTO 480
400 REM DO CHOSEN COMMAND
410 GOSUB 440: VTAB 9: PRINT SPC( 7)AE$(I)
420 PRINT D$"PR#0":Z$ = AC$(I): PRINT D$Z$: IF LEFT$(Z$,4) = "EXEC" THEN END
430 POKE 48688,0: POKE 48689,3: GOTO 640
440 TEXT : HOME : NORMAL : SPEED= 255
450 PRINT " "N$
460 PRINT " ";: FOR S = 1 TO LEN(N$): PRINT "_";: NEXT : PRINT
470 RETURN
480 GOSUB 440: PRINT : IF NP <15 THEN PRINT
490 IF AB = 0 GOTO 520
500 VTAB 11: PRINT " EXPLANATIONS ARE NOT AVAILABLE. ";
510 POKE 49168,0: GET Z$: GOTO 310
520 FOR I = 1 TO NP: PRINT SPC( 3): INVERSE
530 PRINT RIGHT$(" " + STR$(I),3)" ";: NORMAL
540 PRINT " "PD$(I,0): IF NP <9 THEN PRINT
550 NEXT
560 VTAB 23: PRINT " TYPE A NUMBER AND PRESS <RETURN>."
570 VTAB 24: PRINT " OR JUST PRESS <RETURN> TO EXIT.";: HTAB 1
580 VTAB 21: INPUT " EXPLAIN WHICH OF THE FILES: ";Z$
590 IF Z$ = "" GOTO 310
600 I = VAL(Z$): IF I <1 OR I >NP GOTO 480
610 VTAB 4: CALL -958:Z$ = PD$(I,0):ZL = LEN(Z$)
620 Z = 20 -.5 *ZL: PRINT TAB( Z)Z$: PRINT TAB( Z) LEFT$("..............................",ZL)
630 PRINT : FOR J = 1 TO NL(I): PRINT : PRINT PD$(I,J): NEXT
640 VTAB 24: PRINT " PRESS ";: INVERSE : PRINT "SPACE BAR";: NORMAL : PRINT " TO PROCEED. ";
650 GET Z$: VTAB 1: PRINT : GOTO 480
660 DATA 201,224,144,13,72,173,179,251,201,6,240,4,104,41,223,72,104,76,240,253