home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO001.dsk / STARTUP.bas < prev   
BASIC Source File  |  2012-02-16  |  2KB  |  57 lines
  1. 100  REM     STARTUP
  2. 110  REM 
  3. 120  REM  DESCRIBE OR INVOKE THE
  4. 130  REM  PROGRAMS ON THIS DISK. 
  5. 140  REM   SES (COMPUTING) INC.  
  6. 150  NORMAL : PRINT  CHR$(21): TEXT : HOME : VTAB 11
  7. 160 D$ =  CHR$(4):F$ = "MENU": PRINT D$"PREFIX /IAC.42"
  8. 170  PRINT "     READING "F$".  PLEASE WAIT ..."
  9. 180  PRINT D$"OPEN"F$
  10. 190  PRINT D$"READ"F$
  11. 200  INPUT N$: REM  NAME OF DISK
  12. 210  INPUT NA: DIM AE$(NA),AC$(NA)
  13. 220  FOR I = 1 TO NA: INPUT AE$(I),AC$(I): NEXT 
  14. 230  IF  PEEK(49152) = 160  THEN AB = 1: GOTO 280
  15. 240  INPUT NP,ML: DIM NL(NP),PD$(NP,ML)
  16. 250  FOR I = 1 TO NP: INPUT PD$(I,0):J = 0
  17. 260  INPUT Z$: IF Z$ >" "  THEN J = J +1:PD$(I,J) = Z$: GOTO 260
  18. 270 NL(I) = J: NEXT 
  19. 280  PRINT D$"CLOSE"
  20. 290  FOR A = 768 TO 787: READ X: POKE A,X: NEXT 
  21. 300  POKE 48688,0: POKE 48689,3
  22. 310  GOSUB 440
  23. 320  PRINT : PRINT : PRINT : FOR I = 1 TO NA
  24. 330  PRINT "   ";: INVERSE : PRINT  SPC( I <10)I;: NORMAL : PRINT "   "AE$(I): IF NA <8  THEN  PRINT 
  25. 340  NEXT 
  26. 350  VTAB 22: CALL  -958: PRINT "   ENTER A NUMBER FROM 1 TO "NA": ";
  27. 360  POKE 49168,0: INPUT "";Z$
  28. 370 I =  VAL(Z$): IF I <1  OR I >NA GOTO 350
  29. 380  IF I = (NA)  THEN  HOME : END 
  30. 390  IF I = NA -1 GOTO 480
  31. 400  REM DO CHOSEN COMMAND
  32. 410  GOSUB 440: VTAB 9: PRINT  SPC( 7)AE$(I)
  33. 420  PRINT D$"PR#0":Z$ = AC$(I): PRINT D$Z$: IF  LEFT$(Z$,4) = "EXEC"  THEN  END 
  34. 430  POKE 48688,0: POKE 48689,3: GOTO 640
  35. 440  TEXT : HOME : NORMAL : SPEED= 255
  36. 450  PRINT "   "N$
  37. 460  PRINT "   ";: FOR S = 1 TO  LEN(N$): PRINT "_";: NEXT : PRINT 
  38. 470  RETURN 
  39. 480  GOSUB 440: PRINT : IF NP <15  THEN  PRINT 
  40. 490  IF AB = 0 GOTO 520
  41. 500  VTAB 11: PRINT "  EXPLANATIONS ARE NOT AVAILABLE. ";
  42. 510  POKE 49168,0: GET Z$: GOTO 310
  43. 520  FOR I = 1 TO NP: PRINT  SPC( 3): INVERSE 
  44. 530  PRINT  RIGHT$("   " + STR$(I),3)" ";: NORMAL 
  45. 540  PRINT "  "PD$(I,0): IF NP <9  THEN  PRINT 
  46. 550  NEXT 
  47. 560  VTAB 23: PRINT "   TYPE A NUMBER AND PRESS <RETURN>."
  48. 570  VTAB 24: PRINT "   OR JUST PRESS <RETURN> TO EXIT.";: HTAB 1
  49. 580  VTAB 21: INPUT "   EXPLAIN WHICH OF THE FILES: ";Z$
  50. 590  IF Z$ = "" GOTO 310
  51. 600 I =  VAL(Z$): IF I <1  OR I >NP GOTO 480
  52. 610  VTAB 4: CALL  -958:Z$ = PD$(I,0):ZL =  LEN(Z$)
  53. 620 Z = 20 -.5 *ZL: PRINT  TAB( Z)Z$: PRINT  TAB( Z) LEFT$("..............................",ZL)
  54. 630  PRINT : FOR J = 1 TO NL(I): PRINT : PRINT PD$(I,J): NEXT 
  55. 640  VTAB 24: PRINT "   PRESS ";: INVERSE : PRINT "SPACE BAR";: NORMAL : PRINT " TO PROCEED. ";
  56. 650  GET Z$: VTAB 1: PRINT : GOTO 480
  57. 660  DATA 201,224,144,13,72,173,179,251,201,6,240,4,104,41,223,72,104,76,240,253